Source 屬性范例

Source 屬性范例

該范例通過打開三個基于不同數(shù)據(jù)源的 Recordset 對象演示 Source 屬性。

Public Sub SourceX()

   Dim cnn1 As ADODB.Connection

   Dim rstTitles As ADODB.Recordset

   Dim rstPublishers As ADODB.Recordset

   Dim rstPublishersDirect As ADODB.Recordset

   Dim rstTitlesPublishers As ADODB.Recordset

   Dim cmdSQL As ADODB.Command

   Dim strCnn As String

   Dim strSQL As String

   ' 打開連接。

   Set cnn1 = New ADODB.Connection

   strCnn = "Provider=sqloledb;" & _

      "Data Source=srv;Initial Catalog=pubs;User Id=sa;Password=; "

   cnn1.Open strCnn

   ' 打開基于命令對象的記錄集。

   Set cmdSQL = New ADODB.Command

   Set cmdSQL.ActiveConnection = cnn1

   cmdSQL.CommandText = "Select title, type, pubdate " & _

      "FROM titles ORDER BY title"

   Set rstTitles = cmdSQL.Execute()

   ' 打開基于表的記錄集。

   Set rstPublishers = New ADODB.Recordset

   rstPublishers.Open "publishers", strCnn, , , adCmdTable

   ' 打開基于表的記錄集。

   Set rstPublishersDirect = New ADODB.Recordset

   rstPublishersDirect.Open "publishers", strCnn, , , adCmdTableDirect

   ' 打開基于 SQL 字符串的記錄集。

   Set rstTitlesPublishers = New ADODB.Recordset

   strSQL = "SELECT title_ID AS TitleID, title AS Title, " & _

      "publishers.pub_id AS PubID, pub_name AS PubName " & _

      "FROM publishers INNER JOIN titles " & _

      "ON publishers.pub_id = titles.pub_id " & _

      "ORDER BY Title"

   rstTitlesPublishers.Open strSQL, strCnn, , , adCmdText

   ' 使用 Source 屬性顯示每個記錄集的資源。

   MsgBox "rstTitles source: " & vbCr & _

      rstTitles.Source & vbCr & vbCr & _

      "rstPublishers source: " & vbCr & _

      rstPublishers.Source & vbCr & vbCr & _

      "rstPublishersDirect source: " & vbCr & _

      rstPublishersDirect.Source & vbCr & vbCr & _

      "rstTitlesPublishers source: " & vbCr & _

      rstTitlesPublishers.Source

   rstTitles.Close

   rstPublishers.Close

   rstTitlesPublishers.Close

   cnn1.Close

End Sub